| Server IP : 103.119.228.120 / Your IP : 3.147.82.252 Web Server : Apache System : Linux v8.techscape8.com 3.10.0-1160.119.1.el7.tuxcare.els2.x86_64 #1 SMP Mon Jul 15 12:09:18 UTC 2024 x86_64 User : nobody ( 99) PHP Version : 5.6.40 Disable Function : shell_exec,symlink,system,exec,proc_get_status,proc_nice,proc_terminate,define_syslog_variables,syslog,openlog,closelog,escapeshellcmd,passthru,ocinum cols,ini_alter,leak,listen,chgrp,apache_note,apache_setenv,debugger_on,debugger_off,ftp_exec,dl,dll,myshellexec,proc_open,socket_bind,proc_close,escapeshellarg,parse_ini_filepopen,fpassthru,exec,passthru,escapeshellarg,escapeshellcmd,proc_close,proc_open,ini_alter,popen,show_source,proc_nice,proc_terminate,proc_get_status,proc_close,pfsockopen,leak,apache_child_terminate,posix_kill,posix_mkfifo,posix_setpgid,posix_setsid,posix_setuid,dl,symlink,shell_exec,system,dl,passthru,escapeshellarg,escapeshellcmd,myshellexec,c99_buff_prepare,c99_sess_put,fpassthru,getdisfunc,fx29exec,fx29exec2,is_windows,disp_freespace,fx29sh_getupdate,fx29_buff_prepare,fx29_sess_put,fx29shexit,fx29fsearch,fx29ftpbrutecheck,fx29sh_tools,fx29sh_about,milw0rm,imagez,sh_name,myshellexec,checkproxyhost,dosyayicek,c99_buff_prepare,c99_sess_put,c99getsource,c99sh_getupdate,c99fsearch,c99shexit,view_perms,posix_getpwuid,posix_getgrgid,posix_kill,parse_perms,parsesort,view_perms_color,set_encoder_input,ls_setcheckboxall,ls_reverse_all,rsg_read,rsg_glob,selfURL,dispsecinfo,unix2DosTime,addFile,system,get_users,view_size,DirFiles,DirFilesWide,DirPrintHTMLHeaders,GetFilesTotal,GetTitles,GetTimeTotal,GetMatchesCount,GetFileMatchesCount,GetResultFiles,fs_copy_dir,fs_copy_obj,fs_move_dir,fs_move_obj,fs_rmdir,SearchText,getmicrotime MySQL : ON | cURL : ON | WGET : ON | Perl : ON | Python : ON | Sudo : ON | Pkexec : ON Directory : /usr/local/ssl/local/ssl/share/zsh/5.0.2/functions/ |
Upload File : |
#compdef perldoc -value-,PERLDOC,-default-
local curcontext="$curcontext" state line expl args ret=1
typeset -A opt_args
args=( '*:Perl pod pages:->perl-pods' )
if [[ $service = *PERLDOC* ]]; then
compset -q
words=( fake "$words[@]" )
(( CURRENT++ ))
args=()
fi
_arguments -C -s -S -A "-*" \
'(- *)-h[print help information]' \
'(- *)-V[display version information]' \
'-D[describe search for the item]' \
'-t[use plain text output instead of nroff]' \
'-u[show raw Pod source]' \
'*-m[display entire module]:module:_perl_modules' \
'-l[display only filename of the module found]' \
'-F[consider arguments as filenames]' \
'(-q -v)-f+[view documentation for Perl built-in function]:perl builtin function:->perl-builtin-funcs' \
'(-f -v)-q+[search question headings in Perl FAQ]:regular expression' \
'(-f -q)-v+[view documentation for predefined variable]:special variable:->perl-variables' \
'(-d)-T[send output direct to stdout and not via pager]' \
'(-T)-d+[specify output file]:output file:_files' \
'-o+[specify output format]:output format:(man nroff pod rtf text tk xml latex)' \
'-M[specifies module to use for formatting]:module:_perl_modules' \
'-w[specify option to formatter]:option' \
'-X[use an index if present]' \
'-n+[specify replacement for nroff]:nroff replacement:_command_names -e' \
'-r[recursive search]' \
'-i[ignore case]' \
"$args[@]" && ret=0
case $state in
perl-builtin-funcs)
: ${(A)_perl_builtin_funcs:=${(u)${${(M)${(f)"$(_call_program functions \
perldoc -u perlfunc 2>/dev/null)"}:#\=item [a-z]*}#* }%%[^a-z]*}}
_wanted functions expl 'perl built-in function' compadd "$@" -a - \
_perl_builtin_funcs && ret=0
;;
perl-pods)
if (( $+opt_args[-F] )); then
_wanted files expl 'Perl modules and .pods' \
_files -g "*.(pod|pm)(-.)" && ret=0
else
_alternative \
'modules:module: _perl_modules -tP' \
'pods:base pod: _perl_basepods' \
'files:module or .pod file:_files -g "*.(pod|pm)(-.)"' && ret=0
fi
;;
perl-variables)
: ${(A)_perl_special_vars:=${(u)${${${(M)${(f)"$(_call_program variables \
perldoc -u perlvar 2>/dev/null)"}:#\=item [\$\@\%]*}#* }:#\$<I*}}}
_wanted variables expl 'perl special variable' compadd "$@" -a - \
_perl_special_vars && ret=0
;;
esac
return ret